setworldspawn 0 64 0
gamerule spawnRadius 0



# starting island

execute in overworld run forceload add -1 -1 1 1
execute in overworld run forceload remove -1 -1 1 1

execute in overworld run fill 4 63 -1 -1 63 1 grass_block
execute in overworld run fill 4 62 -1 -1 61 1 dirt
execute in overworld run fill 1 63 2 -1 63 4 grass_block
execute in overworld run fill 1 62 2 -1 61 4 dirt
execute in overworld run setblock 0 61 0 bedrock

execute in overworld run place feature oak -1 64 4

execute in overworld run setblock 4 64 0 chest[facing=west]
execute in overworld run item replace block 4 64 0 container.0 with ice 1
execute in overworld run item replace block 4 64 0 container.1 with lava_bucket 1
execute in overworld run item replace block 4 64 0 container.25 with sweet_berries 1
execute in overworld run item replace block 4 64 0 container.26 with glow_berries 1
execute in overworld run item replace block 4 64 0 container.17 with obsidian 10



# nether

execute in the_nether run forceload add -1 -1 1 1
execute in the_nether run forceload remove -1 -1 1 1

execute in the_nether run fill 2 63 0 2 63 1 obsidian
execute in the_nether run fill 2 64 2 2 66 2 obsidian
execute in the_nether run fill 2 67 0 2 67 1 obsidian
execute in the_nether run fill 2 64 -1 2 66 -1 obsidian
execute in the_nether run fill 2 64 0 2 66 1 nether_portal[axis=z]

execute in the_nether run fill 1 63 -1 1 63 2 glowstone
execute in the_nether run fill 3 63 -1 3 63 2 glowstone

execute in the_nether run setblock 1 64 -1 chest[facing=west]
execute in the_nether run item replace block 1 64 -1 container.0 with nether_wart 1



# end

execute in the_end run forceload add -1 -1 112 0
execute in the_end run forceload remove -1 -1 112 0

execute in the_end run setblock 0 61 0 bedrock

execute in the_end run setblock 112 48 0 obsidian
execute in the_end run setblock 112 49 0 chest[facing=west]
execute in the_end run item replace block 112 49 0 container.0 with chorus_flower 1



# set flag
scoreboard players set $initialized vanilla_skyblock_data 1