extends Node


signal stage_state_changed(state: State)

var state: State :
	set(value):
		state = value
		stage_state_changed.emit(value)

var stage: Stage
var player: Player


func _ready():
	player = Player.new()
	player.id = multiplayer.get_unique_id()


func update_player():
	Network.players[multiplayer.get_unique_id()] = player
	Network.update_player.rpc(Network.to_rpc_object(player))


func initialize_stage(current_stage: Stage):
	stage = current_stage


func place_tower(tower: Tower, position: Vector2):
	var network_id = multiplayer.get_unique_id()
	tower.owner_id = network_id
	tower.set_multiplayer_authority(network_id)
	tower.name = "Tower@" + str(network_id) + "@" + str(Time.get_ticks_usec())
	
	stage.place_tower(tower, position)
	Network.place_tower.rpc(Network.to_rpc_object(tower), position)
	
	player.towers[position] = tower
	player.score += 1
	update_player()


func remove_tower(tower: Tower):
	if tower.owner_id == multiplayer.get_unique_id():
		destroy_tower(tower)
		player.score -= 1
		update_player()


func destroy_tower(tower: Tower):
	stage.destroy_tower(tower)
	Network.destroy_tower.rpc(Network.to_rpc_object(tower))
	
	player.towers.erase(tower.global_position)
	update_player()


func select_tower(tower: Tower):
	if tower.owner_id == multiplayer.get_unique_id():
		tower.is_selected = true


func deselect_tower():
	if not Tower.selected_towers.is_empty():
		for tower in Tower.selected_towers:
			tower.is_selected = false


func spawn_unit(unit: Unit, spawn: Spawn):
	var network_id = multiplayer.get_unique_id()
	unit.owner_id = network_id
	unit.set_multiplayer_authority(network_id)
	unit.name = "Unit@" + str(network_id) + "@" + str(Time.get_ticks_usec())
	
	unit.global_position = spawn.spawn_position
	unit.target = spawn.next_node
	unit.hp = randi_range(50, 150) #20000b
	unit.speed = randi_range(100, 150)
	
	stage.spawn_unit(unit, spawn)
	Network.spawn_unit.rpc(Network.to_rpc_object(unit), Network.to_rpc_object(spawn))


func array_intersect(first, second):
	var compare = {}
	for value in first:
		compare[value] = true
	
	for value in second:
		if compare.get(value, false):
			return true
	
	return false